Rules for integrands of the form  u (((a+b Log[c (((d+e (x^n)))^p)]))^q)

0:  ∫(((Subscript[P, q])[x])^m) Log[F[x]]dx  when  m∈ℤ ∧ C==(((((Subscript[P, q])[x])^m) (1-F[x]))/((∂_x)F[x]))

Derivation: Integration by substitution

Basis: If  C==(((((Subscript[P, q])[x])^m) (1-F[x]))/((∂_x)F[x])), then (((Subscript[P, q])[x])^m) Log[F[x]]==C Subst[((Log[x])/(1-x)),x,F[x]](∂_x)F[x]

Rule: If  m∈ℤ ∧ C==(((((Subscript[P, q])[x])^m) (1-F[x]))/((∂_x)F[x])), then

∫(((Subscript[P, q])[x])^m) Log[F[x]]dx  ⟶  C Subst[∫((Log[x])/(1-x))dx,x,u]  ⟶  C PolyLog[2,1-u]

Program code:

Int[Pq_^m_.*Log[u_],x_Symbol] :=
  With[{C=FullSimplify[Pq^m*(1-u)/D[u,x]]},
  C*PolyLog[2,1-u] /;
 FreeQ[C,x]] /; 
IntegerQ[m] && PolyQ[Pq,x] && RationalFunctionQ[u,x] && LeQ[RationalFunctionExponents[u,x][[2]],Expon[Pq,x]]

1.  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1:  ∫Log[c (((d+e (x^n)))^p)]dx

Derivation: Integration by parts

Rule:

∫Log[c (((d+e (x^n)))^p)]dx  ⟶  x Log[c (((d+e (x^n)))^p)]-e n p∫((x^n)/(d+e (x^n)))dx

Program code:

Int[Log[c_.*(d_+e_.*x_^n_)^p_.],x_Symbol] :=
  x*Log[c*(d+e*x^n)^p] - e*n*p*Int[x^n/(d+e*x^n),x] /;
FreeQ[{c,d,e,n,p},x]

2.  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  q∈(SuperPlus[ℤ])∧ (q==1 ∨ n∈ℤ)

1:  ∫(((a+b Log[c (((d+(e/x)))^p)]))^q)dx  when  q∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  q∈(SuperPlus[ℤ]), then

∫(((a+b Log[c (((d+(e/x)))^p)]))^q)dx  ⟶  (((e+d x) (((a+b Log[c (((d+(e/x)))^p)]))^q))/d)+((b e p q)/d) ∫((((a+b Log[c (((d+(e/x)))^p)]))^(q-1))/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_./x_)^p_.])^q_,x_Symbol] :=
  (e+d*x)*(a+b*Log[c*(d+e/x)^p])^q/d + b*e*p*q/d*Int[(a+b*Log[c*(d+e/x)^p])^(q-1)/x,x] /;
FreeQ[{a,b,c,d,e,p},x] && IGtQ[q,0]

2:  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  q∈(SuperPlus[ℤ])∧ (q==1 ∨ n∈ℤ)

Derivation: Integration by parts

Rule: If  q∈(SuperPlus[ℤ])∧ (q==1 ∨ n∈ℤ), then

∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  x (((a+b Log[c (((d+e (x^n)))^p)]))^q)-b e n p q∫(((x^n) (((a+b Log[c (((d+e (x^n)))^p)]))^(q-1)))/(d+e (x^n)))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  x*(a+b*Log[c*(d+e*x^n)^p])^q - b*e*n*p*q*Int[x^n*(a+b*Log[c*(d+e*x^n)^p])^(q-1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && IGtQ[q,0] && (EqQ[q,1] || IntegerQ[n])

x:  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  -1<n<1 ∧ (n>0 ∨ q∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1)) F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  -1<n<1 ∧ (n>0 ∨ q∈(SuperPlus[ℤ])), let k->Denominator[n], then

∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  k Subst[∫(x^(k-1)) (((a+b Log[c (((d+e (x^(k n))))^p)]))^q)dx,x,(x^(1/k))]

Program code:

(* Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*Log[c*(d+e*x^(k*n))^p])^q,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e,p,q},x] && LtQ[-1,n,1] && (GtQ[n,0] || IGtQ[q,0]) *)

3:  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1)) F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽, let k->Denominator[n], then

∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  k Subst[∫(x^(k-1)) (((a+b Log[c (((d+e (x^(k n))))^p)]))^q)dx,x,(x^(1/k))]

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(a+b*Log[c*(d+e*x^(k*n))^p])^q,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e,p,q},x] && FractionQ[n]

U:  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  Unintegrable[(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x]

N:  ∫(((a+b Log[c (v^p)]))^q)dx  when  v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  v==d+e (x^n), then

∫(((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,p,q},x] && BinomialQ[v,x] && Not[BinomialMatchQ[v,x]]

2.  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1.  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  q==1 ∨ (((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ])))

1:  ∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m) F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ])), then

∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((a+b Log[c (((d+e x))^p)]))^q)dx,x,(x^n)]

Program code:

Int[x_^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(a+b*Log[c*(d+e*x)^p])^q,x],x,x^n] /;
FreeQ[{a,b,c,d,e,m,n,p,q},x] && IntegerQ[Simplify[(m+1)/n]] && (GtQ[(m+1)/n,0] || IGtQ[q,0]) && Not[EqQ[q,1] && ILtQ[n,0] && IGtQ[m,0]]

2:  ∫(((f x))^m) (a+b Log[c (((d+e (x^n)))^p)])dx  when  m≠-1

Reference: G&R 2.728.1, CRC 501, A&S 4.1.50'

Derivation: Integration by parts and piecewise constant extraction

Rule: If  m≠-1, then

∫(((f x))^m) (a+b Log[c (((d+e (x^n)))^p)])dx  ⟶  (((((f x))^(m+1)) (a+b Log[c (((d+e (x^n)))^p)]))/(f (m+1)))-((b e n p)/(f (m+1)))∫(((x^(n-1)) (((f x))^(m+1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.]),x_Symbol] :=
  (f*x)^(m+1)*(a+b*Log[c*(d+e*x^n)^p])/(f*(m+1)) - 
  b*e*n*p/(f*(m+1))*Int[x^(n-1)*(f*x)^(m+1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f,m,n,p},x] && NeQ[m,-1]

3:  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ]))

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Rule: If ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ])), then

∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_*x_)^m_*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  (f*x)^m/x^m*Int[x^m*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && IntegerQ[Simplify[(m+1)/n]] && (GtQ[(m+1)/n,0] || IGtQ[q,0])

2:  ∫(((f x))^m)(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  q-1∈(SuperPlus[ℤ])∧ n∈ℤ ∧ m≠-1

Derivation: Integration by parts

Rule: If  q-1∈(SuperPlus[ℤ])∧ n∈ℤ ∧ m≠-1, then

∫(((f x))^m)(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (((((f x))^(m+1)) (((a+b Log[c (((d+e (x^n)))^p)]))^q))/(f (m+1)))-((b e n p q)/((f^n) (m+1)))∫(((((f x))^(m+n)) (((a+b Log[c (((d+e (x^n)))^p)]))^(q-1)))/(d+e (x^n)))dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  (f*x)^(m+1)*(a+b*Log[c*(d+e*x^n)^p])^q/(f*(m+1)) - 
  b*e*n*p*q/(f^n*(m+1))*Int[(f*x)^(m+n)*(a+b*Log[c*(d+e*x^n)^p])^(q-1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f,m,p},x] && IGtQ[q,1] && IntegerQ[n] && NeQ[m,-1]

3.  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽

1:  ∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (x^m) F[(x^n)]==k Subst[(x^(k (m+1)-1)) F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽, let k->Denominator[n], then

∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  k Subst[∫(x^(k (m+1)-1)) (((a+b Log[c (((d+e (x^(k n))))^p)]))^q)dx,x,(x^(1/k))]

Program code:

Int[x_^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k*(m+1)-1)*(a+b*Log[c*(d+e*x^(k*n))^p])^q,x],x,x^(1/k)]] /;
FreeQ[{a,b,c,d,e,m,p,q},x] && FractionQ[n]

2:  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽

Derivation: Piecewise constant extraction

Basis: (∂_x)((((f x))^m)/(x^m))==0

Rule: If  n∈𝔽, then

∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ((((f x))^m)/(x^m)) ∫(x^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_*x_)^m_*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  (f*x)^m/x^m*Int[x^m*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,m,p,q},x] && FractionQ[n]

U:  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(f*x)^m*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x]

N:  ∫(((f x))^m) (((a+b Log[c (v^p)]))^q)dx  when  v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  v==d+e (x^n), then

∫(((f x))^m) (((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((f x))^m) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_.*x_)^m_.*(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[(f*x)^m*(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,f,m,p,q},x] && BinomialQ[v,x] && Not[BinomialMatchQ[v,x]]

3.  ∫(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1.  ∫(((f+g x))^r) (a+b Log[c (((d+e (x^n)))^p)])dx  when  r∈(SuperPlus[ℤ])∨ n∈ℝ

1:  ∫((a+b Log[c (((d+e (x^n)))^p)])/(f+g x))dx  when  n∈ℝ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (((d+e (x^n)))^p)])==((b e n p (x^(n-1)))/(d+e (x^n)))

Rule: If  n∈ℝ, then

∫((a+b Log[c (((d+e (x^n)))^p)])/(f+g x))dx  ⟶  ((Log[f+g x] (a+b Log[c (((d+e (x^n)))^p)]))/g)-((b e n p)/g)∫(((x^(n-1))Log[f+g x])/(d+e (x^n)))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])/(f_.+g_.*x_),x_Symbol] :=
  Log[f+g*x]*(a+b*Log[c*(d+e*x^n)^p])/g - 
  b*e*n*p/g*Int[x^(n-1)*Log[f+g*x]/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && RationalQ[n]

2:  ∫(((f+g x))^r) (a+b Log[c (((d+e (x^n)))^p)])dx  when  (r∈(SuperPlus[ℤ])∨ n∈ℝ) ∧ r≠-1

Reference: G&R 2.728.1, CRC 501, A&S 4.1.50'

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (((d+e (x^n)))^p)])==((b e n p (x^(n-1)))/(d+e (x^n)))

Rule: If (r∈(SuperPlus[ℤ])∨ n∈ℝ) ∧ r≠-1, then

∫(((f+g x))^r) (a+b Log[c (((d+e (x^n)))^p)])dx  ⟶  (((((f+g x))^(r+1)) (a+b Log[c (((d+e (x^n)))^p)]))/(g (r+1)))-((b e n p)/(g (r+1)))∫(((x^(n-1))(((f+g x))^(r+1)))/(d+e (x^n)))dx

Program code:

Int[(f_.+g_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.]),x_Symbol] :=
  (f+g*x)^(r+1)*(a+b*Log[c*(d+e*x^n)^p])/(g*(r+1)) - 
  b*e*n*p/(g*(r+1))*Int[x^(n-1)*(f+g*x)^(r+1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,r},x] && (IGtQ[r,0] || RationalQ[n]) && NeQ[r,-1]

U:  ∫(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_.+g_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(f+g*x)^r*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r},x]

N:  ∫(u^r) (((a+b Log[c (v^p)]))^q)dx  when  u==f+g x ∧ v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  u==f+g x ∧ v==d+e (x^n), then

∫(u^r) (((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[u_^r_.*(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[ExpandToSum[u,x]^r*(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,p,q,r},x] && LinearQ[u,x] && BinomialQ[v,x] && Not[LinearMatchQ[u,x] && BinomialMatchQ[v,x]]

4.  ∫(((h x))^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1:  ∫(x^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  m∈ℤ ∧ r∈ℤ

Derivation: Algebraic expansion

Rule: If  m∈ℤ ∧ r∈ℤ, then

∫(x^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q) ExpandIntegrand[(x^m) (((f+g x))^r),x]dx

Program code:

Int[x_^m_.*(f_.+g_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[c*(d+e*x^n)^p])^q,x^m*(f+g*x)^r,x],x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q},x] && IntegerQ[m] && IntegerQ[r]

2:  ∫(((h x))^m)(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  m∈𝔽 ∧ n∈ℤ ∧ r∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((h x))^m) F[x]==(k/h) Subst[(x^(k (m+1)-1))F[((x^k)/h)],x,(((h x))^(1/k))] (∂_x)(((h x))^(1/k))

Rule: If  m∈𝔽 ∧ n∈ℤ ∧ r∈ℤ, let k=Denominator[m], then

∫(((h x))^m)(((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (k/h) Subst[∫(x^(k (m+1)-1)) (((f+((g (x^k))/h)))^r) (((a+b Log[c (((d+((e (x^(k n)))/h)))^p)]))^q) dx,x,(((h x))^(1/k))]

Program code:

Int[(h_.*x_)^m_*(f_.+g_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_.)^p_.])^q_.,x_Symbol] :=
  With[{k=Denominator[m]},
  k/h*Subst[Int[x^(k*(m+1)-1)*(f+g*x^k/h)^r*(a+b*Log[c*(d+e*x^(k*n)/h^n)^p])^q,x],x,(h*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,g,h,p,r},x] && FractionQ[m] && IntegerQ[n] && IntegerQ[r]

U:  ∫(((h x))^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((h x))^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((h x))^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(h_.*x_)^m_.*(f_.+g_.*x_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(h*x)^m*(f+g*x)^r*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,p,q,r},x]

N:  ∫(((h x))^m) (u^r) (((a+b Log[c (v^p)]))^q)dx  when  u==f+g x ∧ v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  u==f+g x ∧ v==d+e (x^n), then

∫(((h x))^m) (u^r) (((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((h x))^m) (((f+g x))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(h_.*x_)^m_.*u_^r_.*(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[(h*x)^m*ExpandToSum[u,x]^r*(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,h,m,p,q,r},x] && LinearQ[u,x] && BinomialQ[v,x] && Not[LinearMatchQ[u,x] && BinomialMatchQ[v,x]]

5.  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1:  ∫((a+b Log[c (((d+e (x^n)))^p)])/(f+g (x^2)))dx  when  n∈ℤ

Derivation: Integration by parts

Rule: If  n∈ℤ, let u->∫(1/(f+g (x^2)))dx, then

∫((a+b Log[c (((d+e (x^n)))^p)])/(f+g (x^2)))dx  ⟶  u (a+b Log[c (((d+e (x^n)))^p)])-b e n p∫((u (x^(n-1)))/(d+e (x^n)))dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])/(f_+g_.*x_^2),x_Symbol] :=
  With[{u=IntHide[1/(f+g*x^2),x]},  
  u*(a+b*Log[c*(d+e*x^n)^p]) - b*e*n*p*Int[u*x^(n-1)/(d+e*x^n),x]] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && IntegerQ[n]

2:  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈ℤ ∧ q∈(SuperPlus[ℤ])∧ r∈ℤ ∧ s∈ℤ

Derivation: Algebraic expansion

Rule: If  n∈ℤ ∧ q∈(SuperPlus[ℤ])∧ r∈ℤ ∧ s-1∈(SuperPlus[ℤ]), then

∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q) ExpandIntegrand[(((f+g (x^s)))^r),x]dx

Program code:

Int[(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  With[{t=ExpandIntegrand[(a+b*Log[c*(d+e*x^n)^p])^q,(f+g*x^s)^r,x]},
  Int[t,x] /;
 SumQ[t]] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r,s},x] && IntegerQ[n] && IGtQ[q,0] && IntegerQ[r] && IntegerQ[s] && 
  (EqQ[q,1] || GtQ[r,0] && GtQ[s,1] || LtQ[s,0] && LtQ[r,0])

3:  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽 ∧ s Denominator[n]∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽, let k->Denominator[n], if  k s∈ℤ, then

∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  k Subst[∫(x^(k-1)) (((f+g (x^(k s))))^r) (((a+b Log[c (((d+e (x^(k n))))^p)]))^q)dx,x,(x^(1/k))]

Program code:

Int[(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(f+g*x^(k*s))^r*(a+b*Log[c*(d+e*x^(k*n))^p])^q,x],x,x^(1/k)] /;
 IntegerQ[k*s]] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r,s},x] && FractionQ[n]

U:  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(f_+g_.*x_^s_)^r_.(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(f+g*x^s)^r*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r,s},x]

N:  ∫(u^r) (((a+b Log[c (v^p)]))^q)dx  when  u==f+g (x^s) ∧ v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  u==f+g (x^s) ∧ v==d+e (x^n), then

∫(u^r) (((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[u_^r_.*(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[ExpandToSum[u,x]^r*(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,p,q,r},x] && BinomialQ[{u,v},x] && Not[BinomialMatchQ[{u,v},x]]

6.  ∫(((h x))^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

1:  ∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  r∈ℤ ∧ (s/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ]))

Derivation: Integration by substitution

Basis: If ((m+1)/n)∈ℤ, then (x^m) F[(x^n)]==(1/n) Subst[(x^(((m+1)/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If r∈ℤ ∧ (s/n)∈ℤ ∧ ((m+1)/n)∈ℤ ∧ (((m+1)/n)>0 ∨ q∈(SuperPlus[ℤ])), then

∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (1/n) Subst[∫(x^(((m+1)/n)-1)) (((f+g (x^(s/n))))^r) (((a+b Log[c (((d+e x))^p)]))^q)dx,x,(x^n)]

Program code:

Int[x_^m_.*(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  1/n*Subst[Int[x^(Simplify[(m+1)/n]-1)*(f+g*x^(s/n))^r*(a+b*Log[c*(d+e*x)^p])^q,x],x,x^n] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q,r,s},x] && IntegerQ[r] && IntegerQ[s/n] && IntegerQ[Simplify[(m+1)/n]] && (GtQ[(m+1)/n,0] || IGtQ[q,0])

2:  ∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  q∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ ∧ s∈ℤ

Derivation: Algebraic expansion

Rule: If  q∈(SuperPlus[ℤ])∧ m∈ℤ ∧ r∈ℤ ∧ s∈ℤ, then

∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (x^n)))^p)]))^q) ExpandIntegrand[(x^m) (((f+g (x^s)))^r),x]dx

Program code:

Int[x_^m_.*(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Int[ExpandIntegrand[(a+b*Log[c*(d+e*x^n)^p])^q,x^m*(f+g*x^s)^r,x],x] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q,r,s},x] && IGtQ[q,0] && IntegerQ[m] && IntegerQ[r] && IntegerQ[s]

?:  ∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽 ∧ m Denominator[n]∈ℤ ∧ s Denominator[n]∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then F[(x^n)]==k Subst[(x^(k-1))F[(x^(k n))],x,(x^(1/k))] (∂_x)(x^(1/k))

Rule: If  n∈𝔽, let k->Denominator[n], if  k m∈ℤ ∧ k s∈ℤ, then

∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  k Subst[∫(x^(k-1)) (((f+g (x^(k s))))^r) (((a+b Log[c (((d+e (x^(k n))))^p)]))^q)dx,x,(x^(1/k))]

Program code:

Int[(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  With[{k=Denominator[n]},
  k*Subst[Int[x^(k-1)*(f+g*x^(k*s))^r*(a+b*Log[c*(d+e*x^(k*n))^p])^q,x],x,x^(1/k)] /;
 IntegerQ[k*s]] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q,r,s},x] && FractionQ[n]

3:  ∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  n∈𝔽 ∧ (1/n)∈ℤ ∧ (s/n)∈ℤ

Derivation: Integration by substitution

Basis: If (1/n)∈ℤ, then F[(x^n)]==(1/n) Subst[(x^((1/n)-1)) F[x],x,(x^n)] (∂_x)(x^n)

Rule: If  n∈𝔽 ∧ (1/n)∈ℤ ∧ (s/n)∈ℤ, then

∫(x^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (1/n) Subst[∫(x^(m+(1/n)-1)) (((f+g (x^(s/n))))^r) (((a+b Log[c (((d+e x))^p)]))^q)dx,x,(x^n)]

Program code:

Int[x_^m_.*(f_+g_.*x_^s_)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  1/n*Subst[Int[x^(m+1/n-1)*(f+g*x^(s/n))^r*(a+b*Log[c*(d+e*x)^p])^q,x],x,x^n] /;
FreeQ[{a,b,c,d,e,f,g,m,n,p,q,r,s},x] && FractionQ[n] && IntegerQ[1/n] && IntegerQ[s/n]

4:  ∫(((h x))^m)(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  when  m∈𝔽 ∧ n∈ℤ ∧ s∈ℤ

Derivation: Integration by substitution

Basis: If  k∈(SuperPlus[ℤ]), then (((h x))^m) F[x]==(k/h) Subst[(x^(k (m+1)-1))F[((x^k)/h)],x,(((h x))^(1/k))] (∂_x)(((h x))^(1/k))

Rule: If  m∈𝔽 ∧ n∈ℤ ∧ s∈ℤ, let k=Denominator[m], then

∫(((h x))^m)(((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  (k/h) Subst[∫(x^(k (m+1)-1)) (((f+((g (x^(k s)))/h)))^r) (((a+b Log[c (((d+((e (x^(k n)))/h)))^p)]))^q) dx,x,(((h x))^(1/k))]

Program code:

Int[(h_.*x_)^m_*(f_.+g_.*x_^s_.)^r_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_.)^p_.])^q_.,x_Symbol] :=
  With[{k=Denominator[m]},
  k/h*Subst[Int[x^(k*(m+1)-1)*(f+g*x^(k*s)/h^s)^r*(a+b*Log[c*(d+e*x^(k*n)/h^n)^p])^q,x],x,(h*x)^(1/k)]] /;
FreeQ[{a,b,c,d,e,f,g,h,p,r},x] && FractionQ[m] && IntegerQ[n] && IntegerQ[s]

U:  ∫(((h x))^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Rule:

∫(((h x))^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx  ⟶  ∫(((h x))^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(h_.*x_)^m_.*(f_+g_.*x_^s_)^r_.(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(h*x)^m*(f+g*x^s)^r*(a+b*Log[c*(d+e*x^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,h,m,n,p,q,r,s},x]

N:  ∫(((h x))^m) (u^r) (((a+b Log[c (v^p)]))^q)dx  when  u==f+g (x^s) ∧ v==d+e (x^n)

Derivation: Algebraic normalization

Rule: If  u==f+g (x^s) ∧ v==d+e (x^n), then

∫(((h x))^m) (u^r) (((a+b Log[c (v^p)]))^q)dx  ⟶  ∫(((h x))^m) (((f+g (x^s)))^r) (((a+b Log[c (((d+e (x^n)))^p)]))^q)dx

Program code:

Int[(h_.*x_)^m_.*u_^r_.*(a_.+b_.*Log[c_.*v_^p_.])^q_.,x_Symbol] :=
  Int[(h*x)^m*ExpandToSum[u,x]^r*(a+b*Log[c*ExpandToSum[v,x]^p])^q,x] /;
FreeQ[{a,b,c,h,m,p,q,r},x] && BinomialQ[{u,v},x] && Not[BinomialMatchQ[{u,v},x]]

7:  ∫((((Log[f (x^q)])^m) (a+b Log[c (((d+e (x^n)))^p)]))/x)dx  when  m≠-1

Derivation: Integration by parts

Basis: (((Log[c (x^q)])^m)/x)==(∂_x)(((Log[c (x^q)])^(m+1))/(q (m+1)))

Rule: If  m≠-1, then

∫((((Log[f (x^q)])^m) (a+b Log[c (((d+e (x^n)))^p)]))/x)dx  ⟶  ((((Log[f (x^q)])^(m+1)) (a+b Log[c (((d+e (x^n)))^p)]))/(q (m+1)))-((b e n p)/(q (m+1))) ∫(((x^(n-1)) ((Log[f (x^q)])^(m+1)))/(d+e (x^n)))dx

Program code:

Int[Log[f_.*x_^q_.]^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.])/x_,x_Symbol] :=
  Log[f*x^q]^(m+1)*(a+b*Log[c*(d+e*x^n)^p])/(q*(m+1)) - 
  b*e*n*p/(q*(m+1))*Int[x^(n-1)*Log[f*x^q]^(m+1)/(d+e*x^n),x] /;
FreeQ[{a,b,c,d,e,f,m,n,p,q},x] && NeQ[m,-1]

8:  ∫((ArcTrig[f x])^m) (a+b Log[c (((d+e (x^n)))^p)])dx  when  m∈(SuperPlus[ℤ])∧ n-1∈(SuperPlus[ℤ])

Derivation: Integration by parts

Rule: If  m∈(SuperPlus[ℤ])∧ n-1∈(SuperPlus[ℤ]), let u->∫((ArcTrig[f x])^m)dx, then

∫((ArcTrig[f x])^m) (a+b Log[c (((d+e (x^n)))^p)])dx  ⟶  u (a+b Log[c (((d+e (x^n)))^p)])-b e n p∫((u (x^(n-1)))/(d+e (x^n)))dx

Program code:

Int[F_[f_.*x_]^m_.*(a_.+b_.*Log[c_.*(d_+e_.*x_^n_)^p_.]),x_Symbol] :=
  With[{u=IntHide[F[f*x]^m,x]},  
  Dist[a+b*Log[c*(d+e*x^n)^p],u,x] - b*e*n*p*Int[SimplifyIntegrand[u*x^(n-1)/(d+e*x^n),x],x]] /;
FreeQ[{a,b,c,d,e,f,p},x] && MemberQ[{ArcSin,ArcCos,ArcSinh,ArcCosh},F] && IGtQ[m,0] && IGtQ[n,1]

Rules for integrands of the form  u (((a+b Log[c (((d+e (x^n)))^p)]))^q)

1:  ∫(((a+b Log[c (((d+e (((f+g x))^n)))^p)]))^q)dx  when  q∈(SuperPlus[ℤ])∧ (q==1 ∨ n∈ℤ)

Derivation: Integration by substitution

Rule: If  q∈(SuperPlus[ℤ])∧ (q==1 ∨ n∈ℤ), then

∫(((a+b Log[c (((d+e (((f+g x))^n)))^p)]))^q)dx  ⟶  (1/g) Subst[∫(((a+b Log[c (((d+e (x^n)))^p)]))^q)dx,x,f+g x]

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*(f_.+g_.*x_)^n_)^p_.])^q_.,x_Symbol] :=
  1/g*Subst[Int[(a+b*Log[c*(d+e*x^n)^p])^q,x],x,f+g*x] /;
FreeQ[{a,b,c,d,e,f,g,n,p},x] && IGtQ[q,0] && (EqQ[q,1] || IntegerQ[n])

U:  ∫(((a+b Log[c (((d+e (((f+g x))^n)))^p)]))^q)dx

Rule:

∫(((a+b Log[c (((d+e (((f+g x))^n)))^p)]))^q)dx  ⟶  ∫(((a+b Log[c (((d+e (((f+g x))^n)))^p)]))^q)dx

Program code:

Int[(a_.+b_.*Log[c_.*(d_+e_.*(f_.+g_.*x_)^n_)^p_.])^q_.,x_Symbol] :=
  Unintegrable[(a+b*Log[c*(d+e*(f+g*x)^n)^p])^q,x] /;
FreeQ[{a,b,c,d,e,f,g,n,p,q},x]